358 lines
13 KiB
Plaintext
358 lines
13 KiB
Plaintext
|
# Configure paths for SDL
|
||
|
|
# Sam Lantinga 9/21/99
|
||
|
|
# stolen from Manish Singh
|
||
|
|
# stolen back from Frank Belew
|
||
|
|
# stolen from Manish Singh
|
||
|
|
# Shamelessly stolen from Owen Taylor
|
||
|
|
|
||
|
|
dnl AM_PATH_SDL([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
|
||
|
|
dnl Test for SDL, and define SDL_CFLAGS and SDL_LIBS
|
||
|
|
dnl
|
||
|
|
AC_DEFUN(AM_PATH_SDL,
|
||
|
|
[dnl
|
||
|
|
dnl Get the cflags and libraries from the sdl-config script
|
||
|
|
dnl
|
||
|
|
AC_ARG_WITH(sdl-prefix,[ --with-sdl-prefix=PFX Prefix where SDL is installed (optional)],
|
||
|
|
sdl_prefix="$withval", sdl_prefix="")
|
||
|
|
AC_ARG_WITH(sdl-exec-prefix,[ --with-sdl-exec-prefix=PFX Exec prefix where SDL is installed (optional)],
|
||
|
|
sdl_exec_prefix="$withval", sdl_exec_prefix="")
|
||
|
|
AC_ARG_ENABLE(sdltest, [ --disable-sdltest Do not try to compile and run a test SDL program],
|
||
|
|
, enable_sdltest=yes)
|
||
|
|
|
||
|
|
if test x$sdl_exec_prefix != x ; then
|
||
|
|
sdl_args="$sdl_args --exec-prefix=$sdl_exec_prefix"
|
||
|
|
if test x${SDL_CONFIG+set} != xset ; then
|
||
|
|
SDL_CONFIG=$sdl_exec_prefix/bin/sdl-config
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
if test x$sdl_prefix != x ; then
|
||
|
|
sdl_args="$sdl_args --prefix=$sdl_prefix"
|
||
|
|
if test x${SDL_CONFIG+set} != xset ; then
|
||
|
|
SDL_CONFIG=$sdl_prefix/bin/sdl-config
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
|
||
|
|
AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
|
||
|
|
min_sdl_version=ifelse([$1], ,0.11.0,$1)
|
||
|
|
AC_MSG_CHECKING(for SDL - version >= $min_sdl_version)
|
||
|
|
no_sdl=""
|
||
|
|
if test "$SDL_CONFIG" = "no" ; then
|
||
|
|
no_sdl=yes
|
||
|
|
else
|
||
|
|
SDL_CFLAGS=`$SDL_CONFIG $sdlconf_args --cflags`
|
||
|
|
SDL_LIBS=`$SDL_CONFIG $sdlconf_args --libs`
|
||
|
|
|
||
|
|
sdl_major_version=`$SDL_CONFIG $sdl_args --version | \
|
||
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
|
||
|
|
sdl_minor_version=`$SDL_CONFIG $sdl_args --version | \
|
||
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
|
||
|
|
sdl_micro_version=`$SDL_CONFIG $sdl_config_args --version | \
|
||
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
|
||
|
|
if test "x$enable_sdltest" = "xyes" ; then
|
||
|
|
ac_save_CFLAGS="$CFLAGS"
|
||
|
|
ac_save_LIBS="$LIBS"
|
||
|
|
CFLAGS="$CFLAGS $SDL_CFLAGS"
|
||
|
|
LIBS="$LIBS $SDL_LIBS"
|
||
|
|
dnl
|
||
|
|
dnl Now check if the installed SDL is sufficiently new. (Also sanity
|
||
|
|
dnl checks the results of sdl-config to some extent
|
||
|
|
dnl
|
||
|
|
rm -f conf.sdltest
|
||
|
|
AC_TRY_RUN([
|
||
|
|
#include <stdio.h>
|
||
|
|
#include <stdlib.h>
|
||
|
|
#include <string.h>
|
||
|
|
#include <SDL.h>
|
||
|
|
|
||
|
|
char*
|
||
|
|
my_strdup (char *str)
|
||
|
|
{
|
||
|
|
char *new_str;
|
||
|
|
|
||
|
|
if (str)
|
||
|
|
{
|
||
|
|
new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
|
||
|
|
strcpy (new_str, str);
|
||
|
|
}
|
||
|
|
else
|
||
|
|
new_str = NULL;
|
||
|
|
|
||
|
|
return new_str;
|
||
|
|
}
|
||
|
|
|
||
|
|
int main (int argc, char *argv[])
|
||
|
|
{
|
||
|
|
int major, minor, micro;
|
||
|
|
char *tmp_version;
|
||
|
|
|
||
|
|
/* This hangs on some systems (?)
|
||
|
|
system ("touch conf.sdltest");
|
||
|
|
*/
|
||
|
|
{ FILE *fp = fopen("conf.sdltest", "a"); if ( fp ) fclose(fp); }
|
||
|
|
|
||
|
|
/* HP/UX 9 (%@#!) writes to sscanf strings */
|
||
|
|
tmp_version = my_strdup("$min_sdl_version");
|
||
|
|
if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, µ) != 3) {
|
||
|
|
printf("%s, bad version string\n", "$min_sdl_version");
|
||
|
|
exit(1);
|
||
|
|
}
|
||
|
|
|
||
|
|
if (($sdl_major_version > major) ||
|
||
|
|
(($sdl_major_version == major) && ($sdl_minor_version > minor)) ||
|
||
|
|
(($sdl_major_version == major) && ($sdl_minor_version == minor) && ($sdl_micro_version >= micro)))
|
||
|
|
{
|
||
|
|
return 0;
|
||
|
|
}
|
||
|
|
else
|
||
|
|
{
|
||
|
|
printf("\n*** 'sdl-config --version' returned %d.%d.%d, but the minimum version\n", $sdl_major_version, $sdl_minor_version, $sdl_micro_version);
|
||
|
|
printf("*** of SDL required is %d.%d.%d. If sdl-config is correct, then it is\n", major, minor, micro);
|
||
|
|
printf("*** best to upgrade to the required version.\n");
|
||
|
|
printf("*** If sdl-config was wrong, set the environment variable SDL_CONFIG\n");
|
||
|
|
printf("*** to point to the correct copy of sdl-config, and remove the file\n");
|
||
|
|
printf("*** config.cache before re-running configure\n");
|
||
|
|
return 1;
|
||
|
|
}
|
||
|
|
}
|
||
|
|
|
||
|
|
],, no_sdl=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
|
||
|
|
CFLAGS="$ac_save_CFLAGS"
|
||
|
|
LIBS="$ac_save_LIBS"
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
if test "x$no_sdl" = x ; then
|
||
|
|
AC_MSG_RESULT(yes)
|
||
|
|
ifelse([$2], , :, [$2])
|
||
|
|
else
|
||
|
|
AC_MSG_RESULT(no)
|
||
|
|
if test "$SDL_CONFIG" = "no" ; then
|
||
|
|
echo "*** The sdl-config script installed by SDL could not be found"
|
||
|
|
echo "*** If SDL was installed in PREFIX, make sure PREFIX/bin is in"
|
||
|
|
echo "*** your path, or set the SDL_CONFIG environment variable to the"
|
||
|
|
echo "*** full path to sdl-config."
|
||
|
|
else
|
||
|
|
if test -f conf.sdltest ; then
|
||
|
|
:
|
||
|
|
else
|
||
|
|
echo "*** Could not run SDL test program, checking why..."
|
||
|
|
CFLAGS="$CFLAGS $SDL_CFLAGS"
|
||
|
|
LIBS="$LIBS $SDL_LIBS"
|
||
|
|
AC_TRY_LINK([
|
||
|
|
#include <stdio.h>
|
||
|
|
#include <SDL.h>
|
||
|
|
], [ return 0; ],
|
||
|
|
[ echo "*** The test program compiled, but did not run. This usually means"
|
||
|
|
echo "*** that the run-time linker is not finding SDL or finding the wrong"
|
||
|
|
echo "*** version of SDL. If it is not finding SDL, you'll need to set your"
|
||
|
|
echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
|
||
|
|
echo "*** to the installed location Also, make sure you have run ldconfig if that"
|
||
|
|
echo "*** is required on your system"
|
||
|
|
echo "***"
|
||
|
|
echo "*** If you have an old version installed, it is best to remove it, although"
|
||
|
|
echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
|
||
|
|
[ echo "*** The test program failed to compile or link. See the file config.log for the"
|
||
|
|
echo "*** exact error that occured. This usually means SDL was incorrectly installed"
|
||
|
|
echo "*** or that you have moved SDL since it was installed. In the latter case, you"
|
||
|
|
echo "*** may want to edit the sdl-config script: $SDL_CONFIG" ])
|
||
|
|
CFLAGS="$ac_save_CFLAGS"
|
||
|
|
LIBS="$ac_save_LIBS"
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
SDL_CFLAGS=""
|
||
|
|
SDL_LIBS=""
|
||
|
|
ifelse([$3], , :, [$3])
|
||
|
|
fi
|
||
|
|
AC_SUBST(SDL_CFLAGS)
|
||
|
|
AC_SUBST(SDL_LIBS)
|
||
|
|
rm -f conf.sdltest
|
||
|
|
])
|
||
|
|
|
||
|
|
/* Steven G. Johnson <stevenj@alum.mit.edu> and Alejandro Forero Cuervo <bachue@bachue.com> */
|
||
|
|
AC_DEFUN([ACX_PTHREAD], [
|
||
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
||
|
|
AC_LANG_SAVE
|
||
|
|
AC_LANG_C
|
||
|
|
acx_pthread_ok=no
|
||
|
|
|
||
|
|
# We used to check for pthread.h first, but this fails if pthread.h
|
||
|
|
# requires special compiler flags (e.g. on True64 or Sequent).
|
||
|
|
# It gets checked for in the link test anyway.
|
||
|
|
|
||
|
|
# First of all, check if the user has set any of the PTHREAD_LIBS,
|
||
|
|
# etcetera environment variables, and if threads linking works using
|
||
|
|
# them:
|
||
|
|
if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
|
||
|
|
save_CFLAGS="$CFLAGS"
|
||
|
|
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
|
||
|
|
save_LIBS="$LIBS"
|
||
|
|
LIBS="$PTHREAD_LIBS $LIBS"
|
||
|
|
AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
|
||
|
|
AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
|
||
|
|
AC_MSG_RESULT($acx_pthread_ok)
|
||
|
|
if test x"$acx_pthread_ok" = xno; then
|
||
|
|
PTHREAD_LIBS=""
|
||
|
|
PTHREAD_CFLAGS=""
|
||
|
|
fi
|
||
|
|
LIBS="$save_LIBS"
|
||
|
|
CFLAGS="$save_CFLAGS"
|
||
|
|
fi
|
||
|
|
|
||
|
|
# We must check for the threads library under a number of different
|
||
|
|
# names; the ordering is very important because some systems
|
||
|
|
# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
|
||
|
|
# libraries is broken (non-POSIX).
|
||
|
|
|
||
|
|
# Create a list of thread flags to try. Items starting with a "-" are
|
||
|
|
# C compiler flags, and other items are library names, except for "none"
|
||
|
|
# which indicates that we try without any flags at all.
|
||
|
|
|
||
|
|
acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt"
|
||
|
|
|
||
|
|
# The ordering *is* (sometimes) important. Some notes on the
|
||
|
|
# individual items follow:
|
||
|
|
|
||
|
|
# pthreads: AIX (must check this before -lpthread)
|
||
|
|
# none: in case threads are in libc; should be tried before -Kthread and
|
||
|
|
# other compiler flags to prevent continual compiler warnings
|
||
|
|
# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
|
||
|
|
# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
|
||
|
|
# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
|
||
|
|
# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
|
||
|
|
# -pthreads: Solaris/gcc
|
||
|
|
# -mthreads: Mingw32/gcc, Lynx/gcc
|
||
|
|
# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
|
||
|
|
# doesn't hurt to check since this sometimes defines pthreads too;
|
||
|
|
# also defines -D_REENTRANT)
|
||
|
|
# pthread: Linux, etcetera
|
||
|
|
# --thread-safe: KAI C++
|
||
|
|
|
||
|
|
case "${host_cpu}-${host_os}" in
|
||
|
|
*solaris*)
|
||
|
|
|
||
|
|
# On Solaris (at least, for some versions), libc contains stubbed
|
||
|
|
# (non-functional) versions of the pthreads routines, so link-based
|
||
|
|
# tests will erroneously succeed. (We need to link with -pthread or
|
||
|
|
# -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
|
||
|
|
# a function called by this macro, so we could check for that, but
|
||
|
|
# who knows whether they'll stub that too in a future libc.) So,
|
||
|
|
# we'll just look for -pthreads and -lpthread first:
|
||
|
|
|
||
|
|
acx_pthread_flags="-pthread -pthreads pthread -mt $acx_pthread_flags"
|
||
|
|
;;
|
||
|
|
esac
|
||
|
|
|
||
|
|
if test x"$acx_pthread_ok" = xno; then
|
||
|
|
for flag in $acx_pthread_flags; do
|
||
|
|
|
||
|
|
case $flag in
|
||
|
|
none)
|
||
|
|
AC_MSG_CHECKING([whether pthreads work without any flags])
|
||
|
|
;;
|
||
|
|
|
||
|
|
-*)
|
||
|
|
AC_MSG_CHECKING([whether pthreads work with $flag])
|
||
|
|
PTHREAD_CFLAGS="$flag"
|
||
|
|
;;
|
||
|
|
|
||
|
|
*)
|
||
|
|
AC_MSG_CHECKING([for the pthreads library -l$flag])
|
||
|
|
PTHREAD_LIBS="-l$flag"
|
||
|
|
;;
|
||
|
|
esac
|
||
|
|
|
||
|
|
save_LIBS="$LIBS"
|
||
|
|
save_CFLAGS="$CFLAGS"
|
||
|
|
LIBS="$PTHREAD_LIBS $LIBS"
|
||
|
|
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
|
||
|
|
|
||
|
|
# Check for various functions. We must include pthread.h,
|
||
|
|
# since some functions may be macros. (On the Sequent, we
|
||
|
|
# need a special flag -Kthread to make this header compile.)
|
||
|
|
# We check for pthread_join because it is in -lpthread on IRIX
|
||
|
|
# while pthread_create is in libc. We check for pthread_attr_init
|
||
|
|
# due to DEC craziness with -lpthreads. We check for
|
||
|
|
# pthread_cleanup_push because it is one of the few pthread
|
||
|
|
# functions on Solaris that doesn't have a non-functional libc stub.
|
||
|
|
# We try pthread_create on general principles.
|
||
|
|
AC_TRY_LINK([#include <pthread.h>],
|
||
|
|
[pthread_t th; pthread_join(th, 0);
|
||
|
|
pthread_attr_init(0); pthread_cleanup_push(0, 0);
|
||
|
|
pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
|
||
|
|
[acx_pthread_ok=yes])
|
||
|
|
|
||
|
|
LIBS="$save_LIBS"
|
||
|
|
CFLAGS="$save_CFLAGS"
|
||
|
|
|
||
|
|
AC_MSG_RESULT($acx_pthread_ok)
|
||
|
|
if test "x$acx_pthread_ok" = xyes; then
|
||
|
|
break;
|
||
|
|
fi
|
||
|
|
|
||
|
|
PTHREAD_LIBS=""
|
||
|
|
PTHREAD_CFLAGS=""
|
||
|
|
done
|
||
|
|
fi
|
||
|
|
|
||
|
|
# Various other checks:
|
||
|
|
if test "x$acx_pthread_ok" = xyes; then
|
||
|
|
save_LIBS="$LIBS"
|
||
|
|
LIBS="$PTHREAD_LIBS $LIBS"
|
||
|
|
save_CFLAGS="$CFLAGS"
|
||
|
|
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
|
||
|
|
|
||
|
|
# Detect AIX lossage: threads are created detached by default
|
||
|
|
# and the JOINABLE attribute has a nonstandard name (UNDETACHED).
|
||
|
|
AC_MSG_CHECKING([for joinable pthread attribute])
|
||
|
|
AC_TRY_LINK([#include <pthread.h>],
|
||
|
|
[int attr=PTHREAD_CREATE_JOINABLE;],
|
||
|
|
ok=PTHREAD_CREATE_JOINABLE, ok=unknown)
|
||
|
|
if test x"$ok" = xunknown; then
|
||
|
|
AC_TRY_LINK([#include <pthread.h>],
|
||
|
|
[int attr=PTHREAD_CREATE_UNDETACHED;],
|
||
|
|
ok=PTHREAD_CREATE_UNDETACHED, ok=unknown)
|
||
|
|
fi
|
||
|
|
if test x"$ok" != xPTHREAD_CREATE_JOINABLE; then
|
||
|
|
AC_DEFINE(PTHREAD_CREATE_JOINABLE, $ok,
|
||
|
|
[Define to the necessary symbol if this constant
|
||
|
|
uses a non-standard name on your system.])
|
||
|
|
fi
|
||
|
|
AC_MSG_RESULT(${ok})
|
||
|
|
if test x"$ok" = xunknown; then
|
||
|
|
AC_MSG_WARN([we do not know how to create joinable pthreads])
|
||
|
|
fi
|
||
|
|
|
||
|
|
AC_MSG_CHECKING([if more special flags are required for pthreads])
|
||
|
|
flag=no
|
||
|
|
case "${host_cpu}-${host_os}" in
|
||
|
|
*-aix* | *-freebsd*) flag="-D_THREAD_SAFE";;
|
||
|
|
*solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
|
||
|
|
esac
|
||
|
|
AC_MSG_RESULT(${flag})
|
||
|
|
if test "x$flag" != xno; then
|
||
|
|
PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
|
||
|
|
fi
|
||
|
|
|
||
|
|
LIBS="$save_LIBS"
|
||
|
|
CFLAGS="$save_CFLAGS"
|
||
|
|
|
||
|
|
# More AIX lossage: must compile with cc_r
|
||
|
|
AC_CHECK_PROG(PTHREAD_CC, cc_r, cc_r, ${CC})
|
||
|
|
else
|
||
|
|
PTHREAD_CC="$CC"
|
||
|
|
fi
|
||
|
|
|
||
|
|
AC_SUBST(PTHREAD_LIBS)
|
||
|
|
AC_SUBST(PTHREAD_CFLAGS)
|
||
|
|
AC_SUBST(PTHREAD_CC)
|
||
|
|
|
||
|
|
# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
|
||
|
|
if test x"$acx_pthread_ok" = xyes; then
|
||
|
|
ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
|
||
|
|
:
|
||
|
|
else
|
||
|
|
acx_pthread_ok=no
|
||
|
|
$2
|
||
|
|
fi
|
||
|
|
AC_LANG_RESTORE
|
||
|
|
])dnl ACX_PTHREAD
|