Merge pull request #4230 from ligfx/build_vendored_libusb

Build vendored libusb with CMake if on Apple or not available system-wide

CMakeLists.txt

@@ -273,10 +273,9 @@ if(APPLE)
 		# increase the chance of not depending on a bunch of copies of them
 		# installed by MacPorts, Fink, Homebrew, etc, and ending up copying
 		# them into the bundle.  Since we optionally depend on libraries which
-		# are not part of OS X (ffmpeg, libusb, etc.), however, don't remove
+		# are not part of OS X (ffmpeg, etc.), however, don't remove the default
-		# the default path entirely as was done in a previous version of this
+		# path entirely as was done in a previous version of this file.  This is
-		# file.  This is still kinda evil, since it defeats the user's path
+		# still kinda evil, since it defeats the user's path settings...
-		# settings...
 		# See http://www.cmake.org/cmake/help/v3.0/command/find_program.html
 		set(CMAKE_PREFIX_PATH "${CMAKE_PREFIX_PATH};/usr")
 	endif()
@@ -743,12 +742,20 @@ if(ENABLE_SDL)
 	endif(SDL2_FOUND)
 endif()
 
-include(FindLibUSB OPTIONAL)
+if(NOT ANDROID)
-if(LIBUSB_FOUND)
+        add_definitions(-D__LIBUSB__)
-	message("Using shared LibUSB")
+        if(NOT APPLE)
-	add_definitions(-D__LIBUSB__)
+	        find_package(LibUSB)
-	include_directories(${LIBUSB_INCLUDE_DIR})
+        endif()
-endif(LIBUSB_FOUND)
+        if(LIBUSB_FOUND AND NOT APPLE)
+	        message("Using shared LibUSB")
+        	include_directories(${LIBUSB_INCLUDE_DIR})
+        else()
+	        message("Using static LibUSB from Externals")
+        	add_subdirectory(Externals/libusb)
+	        set(LIBUSB_LIBRARIES usb)
+        endif()
+endif()
 
 set(SFML_REQD_VERSION 2.1)
 if(NOT APPLE)

Externals/libusb/CMakeLists.txt

@@ -0,0 +1,113 @@
+add_library(usb SHARED EXCLUDE_FROM_ALL
+    libusb/core.c
+    libusb/core.c
+    libusb/descriptor.c
+    libusb/hotplug.c
+    libusb/io.c
+    libusb/strerror.c
+    libusb/sync.c
+)
+set_target_properties(usb PROPERTIES VERSION 1.0.19)
+target_include_directories(usb
+    # turns out other projects also have "config.h", so make sure the
+    # LibUSB one comes first
+    BEFORE
+
+    PUBLIC libusb
+    PRIVATE "${CMAKE_CURRENT_BINARY_DIR}"
+)
+
+if(WIN32 OR CYGWIN)
+    target_sources(usb PRIVATE libusb/os/windows_usb.c)
+    set(OS_WINDOWS TRUE)
+elseif(APPLE)
+    target_sources(usb PRIVATE libusb/os/darwin_usb.c)
+    find_library(COREFOUNDATION_LIBRARY CoreFoundation)
+    find_library(IOKIT_LIBRARY IOKit)
+    find_library(OBJC_LIBRARY objc)
+    target_link_libraries(usb PRIVATE
+        ${COREFOUNDATION_LIBRARY}
+        ${IOKIT_LIBRARY}
+        ${OBJC_LIBRARY}
+    )
+    set(OS_DARWIN TRUE)
+# # Dolphin on Android doesn't use libusb.
+#elseif(ANDROID)
+#    target_sources(usb PRIVATE
+#        libusb/os/linux_usbfs.c
+#        libusb/os/linux_netlink.c
+#    )
+#    find_library(LOG_LIBRARY log)
+#    target_link_libraries(usb PRIVATE ${LOG_LIBRARY})
+#    set(OS_LINUX TRUE)
+elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
+    target_sources(usb PRIVATE libusb/os/linux_usbfs.c)
+    find_package(Libudev)
+    if(LIBUDEV_FOUND)
+        target_sources(usb PRIVATE libusb/os/linux_udev.c)
+        target_link_libraries(usb PRIVATE "${LIBUDEV_LIBRARIES}")
+        target_include_directories(usb PRIVATE "${LIBUDEV_INCLUDE_DIR}")
+        set(HAVE_LIBUDEV TRUE)
+        set(USE_LIBUDEV TRUE)
+    else()
+        target_sources(usb PRIVATE libusb/os/linux_netlink.c)
+    endif()
+    set(OS_LINUX TRUE)
+elseif(${CMAKE_SYSTEM_NAME} MATCHES "NetBSD")
+    target_sources(usb PRIVATE libusb/os/netbsd_usb.c)
+    set(OS_NETBSD TRUE)
+elseif(${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD")
+    target_sources(usb PRIVATE libusb/os/openbsd_usb.c)
+    set(OS_OPENBSD TRUE)
+endif()
+
+if(UNIX)
+    target_sources(usb PRIVATE
+        libusb/os/poll_posix.c
+        libusb/os/threads_posix.c
+    )
+    find_package(Threads REQUIRED)
+    if(THREADS_HAVE_PTHREAD_ARG)
+      target_compile_options(usb PUBLIC "-pthread")
+    endif()
+    if(CMAKE_THREAD_LIBS_INIT)
+      target_link_libraries(usb PRIVATE "${CMAKE_THREAD_LIBS_INIT}")
+    endif()
+    set(THREADS_POSIX TRUE)
+elseif(WIN32)
+    target_sources(usb PRIVATE
+        libusb/os/poll_windows.c
+        libusb/os/threads_windows.c
+    )
+endif()
+
+include(CheckFunctionExists)
+include(CheckIncludeFiles)
+include(CheckTypeSize)
+check_include_files(asm/types.h HAVE_ASM_TYPES_H)
+check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
+check_include_files(linux/filter.h HAVE_LINUX_FILTER_H)
+check_include_files(linux/netlink.h HAVE_LINUX_NETLINK_H)
+check_include_files(poll.h HAVE_POLL_H)
+check_include_files(signal.h HAVE_SIGNAL_H)
+check_include_files(strings.h HAVE_STRINGS_H)
+check_type_size("struct timespec" STRUCT_TIMESPEC)
+check_function_exists(syslog HAVE_SYSLOG_FUNC)
+check_include_files(syslog.h HAVE_SYSLOG_H)
+check_include_files(sys/socket.h HAVE_SYS_SOCKET_H)
+check_include_files(sys/time.h HAVE_SYS_TIME_H)
+check_include_files(sys/types.h HAVE_SYS_TYPES_H)
+
+set(CMAKE_EXTRA_INCLUDE_FILES poll.h)
+check_type_size("nfds_t" nfds_t)
+unset(CMAKE_EXTRA_INCLUDE_FILES)
+if(HAVE_NFDS_T)
+    set(POLL_NFDS_TYPE "nfds_t")
+else()
+    set(POLL_NFDS_TYPE "unsigned int")
+endif()
+
+check_include_files(sys/timerfd.h USBI_TIMERFD_AVAILABLE)
+
+
+configure_file(config.h.in config.h)

Externals/libusb/config.h.in

@@ -0,0 +1,86 @@
+/* Default visibility */
+#define DEFAULT_VISIBILITY __attribute__((visibility("default")))
+
+/* Start with debug message logging enabled */
+#undef ENABLE_DEBUG_LOGGING
+
+/* Message logging */
+#undef ENABLE_LOGGING
+
+/* Define to 1 if you have the <asm/types.h> header file. */
+#cmakedefine HAVE_ASM_TYPES_H 1
+
+/* Define to 1 if you have the `gettimeofday' function. */
+#cmakedefine HAVE_GETTIMEOFDAY 1
+
+/* Define to 1 if you have the `udev' library (-ludev). */
+#cmakedefine HAVE_LIBUDEV 1
+
+/* Define to 1 if you have the <linux/filter.h> header file. */
+#cmakedefine HAVE_LINUX_FILTER_H 1
+
+/* Define to 1 if you have the <linux/netlink.h> header file. */
+#cmakedefine HAVE_LINUX_NETLINK_H 1
+
+/* Define to 1 if you have the <poll.h> header file. */
+#cmakedefine HAVE_POLL_H 1
+
+/* Define to 1 if you have the <signal.h> header file. */
+#cmakedefine HAVE_SIGNAL_H 1
+
+/* Define to 1 if you have the <strings.h> header file. */
+#cmakedefine HAVE_STRINGS_H 1
+
+/* Define to 1 if the system has the type `struct timespec'. */
+#cmakedefine HAVE_STRUCT_TIMESPEC 1
+
+/* syslog() function available */
+#cmakedefine HAVE_SYSLOG_FUNC 1
+
+/* Define to 1 if you have the <syslog.h> header file. */
+#cmakedefine HAVE_SYSLOG_H 1
+
+/* Define to 1 if you have the <sys/socket.h> header file. */
+#cmakedefine HAVE_SYS_SOCKET_H 1
+
+/* Define to 1 if you have the <sys/time.h> header file. */
+#cmakedefine HAVE_SYS_TIME_H 1
+
+/* Define to 1 if you have the <sys/types.h> header file. */
+#cmakedefine HAVE_SYS_TYPES_H 1
+
+/* Darwin backend */
+#cmakedefine OS_DARWIN 1
+
+/* Linux backend */
+#cmakedefine OS_LINUX 1
+
+/* NetBSD backend */
+#cmakedefine OS_NETBSD 1
+
+/* OpenBSD backend */
+#cmakedefine OS_OPENBSD 1
+
+/* Windows backend */
+#cmakedefine OS_WINDOWS 1
+
+/* type of second poll() argument */
+#define POLL_NFDS_TYPE @POLL_NFDS_TYPE@
+
+/* Use POSIX Threads */
+#cmakedefine THREADS_POSIX
+
+/* timerfd headers available */
+#cmakedefine USBI_TIMERFD_AVAILABLE 1
+
+/* Enable output to system log */
+#define USE_SYSTEM_LOGGING_FACILITY 1
+
+/* Use udev for device enumeration/hotplug */
+#cmakedefine USE_UDEV 1
+
+/* Use GNU extensions */
+#define _GNU_SOURCE
+
+/* Oldest Windows version supported */
+#define WINVER 0x0501

Source/Core/InputCommon/CMakeLists.txt

@@ -32,13 +32,12 @@ elseif(ANDROID)
 	         ControllerInterface/Android/Android.cpp)
 endif()
 
-if(LIBUSB_FOUND)
+if(ANDROID)
-	set(SRCS	${SRCS}	GCAdapter.cpp)
+        set(SRCS        ${SRCS} GCAdapter_Android.cpp)
-elseif(ANDROID)
-	set(SRCS	${SRCS}	GCAdapter_Android.cpp)
 else()
-	set(SRCS	${SRCS}	GCAdapter_Null.cpp)
+        set(SRCS        ${SRCS} GCAdapter.cpp)
-endif(LIBUSB_FOUND)
+        set(LIBS ${LIBS} ${LIBUSB_LIBRARIES})
+endif()
 
 if(LIBEVDEV_FOUND AND LIBUDEV_FOUND)
 	set(SRCS ${SRCS} ControllerInterface/evdev/evdev.cpp)

Source/Core/InputCommon/GCAdapter_Null.cpp

@@ -1,53 +0,0 @@
-// Copyright 2014 Dolphin Emulator Project
-// Licensed under GPLv2+
-// Refer to the license.txt file included.
-
-#include "InputCommon/GCAdapter.h"
-#include "Common/CommonTypes.h"
-#include "InputCommon/GCPadStatus.h"
-
-namespace GCAdapter
-{
-void Init()
-{
-}
-void ResetRumble()
-{
-}
-void Shutdown()
-{
-}
-void SetAdapterCallback(std::function<void(void)> func)
-{
-}
-void StartScanThread()
-{
-}
-void StopScanThread()
-{
-}
-GCPadStatus Input(int chan)
-{
-  return {};
-}
-void Output(int chan, u8 rumble_command)
-{
-}
-bool IsDetected()
-{
-  return false;
-}
-bool IsDriverDetected()
-{
-  return false;
-}
-bool DeviceConnected(int chan)
-{
-  return false;
-}
-bool UseAdapter()
-{
-  return false;
-}
-
-}  // end of namespace GCAdapter